quinta-feira, 15 de março de 2001

Veja os drives do servidor

<%


'*************************************************************
'* Nome do Script: DiskInfo - v1.0                   *
'* Arquivo: diskinfo.asp                                     *
'* Descrição: Mostra informações de utilização de discos     *
'*            no servidor                  *
'* Autor: Cass Surek - cs@master.com.br                      *
'* Data: 24/07/1999                                          *
'* Obs: - Modifique as configurações para suas necessidades  *
'*      - Modifique os campos do arquivo texto se preciso,   *
'*          na primeira linha do txt                         *
'*                                                           *
'* -Use o script à vontade, só mande um e-mail para          *
'*  que eu saiba que o script foi útil. :-)                  *
'* -Mande suas sugestões para melhoria!                      *
'* -Por favor, não retire este cabeçalho.                    *
'*************************************************************


 
 Option Explicit
 Response.Buffer = True
 
 Dim ObjFSO, ObjDrivesCol, ObjDrive
 Dim Num_Drives, Drive
 Dim i, item, Pronto, Tipo
 Dim Reg_Estilo1, Reg_Estilo2, Reg_Estilo3, Reg_Estilo4
 Dim Tab_Larg, Tab_Bord, Tab_Cab_Cor, Tab_CabT_Cor, Tab_Reg_Cor, Tab_RegT_Cor, Tab_Al
 Dim Tab_Cell_Spacing, Tab_Cell_Padding, Det_Scr


 
 '*****************
 '* Configurações *
 '*****************
 
 'Tabela
 '-------------
 
  'Qual é a largura da Tabela? (em pixels, ex: 580 ou porcentagem, ex: 90%)
  Tab_Larg = "300"
 
  'Qual é a borda da Tabela? (em pixels)
  Tab_Bord = 0
 
  'Qual é a cor do cabeçalho da Tabela? (em hexadecimal, #000000 = Preto, #FFFFFF = Branco)
  Tab_Cab_Cor = "#0000FF"
 
  'Qual é a cor do texto do cabeçalho da Tabela? (em hexadecimal, #000000 = Preto, #FFFFFF = Branco)
  Tab_CabT_Cor = "#FFFFFF"


  'Qual é o espaçamento entre células da tabela? (em pixels)
  Tab_Cell_Spacing = 1
  
  'Qual é o espaçamento entre a borda da célula e o texto? (em pixels)
  Tab_Cell_Padding = 4


 
 
 'Extras
 '------
 
  'Mostrar Título do Script? <Sim/Não>
  Det_Scr = "Sim"


 '***********
 '* Funções *
 '***********


 Public Function Erro(mensagem)
 
  Response.Write "<p><strong><font face=" & Chr(34) & "Arial" & Chr(34) & _
                 "color=" & Chr(34) & "#0000FF" & Chr(34) & "> " & _
                 "Erro!!! " & mensagem & "</font></strong></p><br>"
  
 End Function
 


 Public Function Cabeca()
 
    %>

 
    <center>
    <font face="Arial" Size="+3" color="#0000FF">Script DiskInfo <br></font>
    <font face="Arial"><small>Cass Surek - <a href="mailto:cs@master.com.br">cs@master.com.br</a><br></small></font>
    <font face="Arial"><small>Versão 1.0 - última alteração feita em 25/07/1999</small></font>
    <br><br>
    </center>


    <%
   
 End Function
 
 '**********
 '* Início *
 '**********
 
 Reg_Estilo1 = "<tr><td" & " width=" & Chr(34) & "50%" & Chr(34) & " bgcolor=" & Chr(34) & "#999999" & Chr(34) & "><font face=" & Chr(34) & "Arial" & Chr(34) & "color=" & Chr(34) & "#000000" & Chr(34) & "><small><strong>"
 Reg_Estilo2 = "</td>"
 Reg_Estilo3 = "<td" & " width=" & Chr(34) & "50%" & Chr(34) & " bgcolor=" & Chr(34) & "#444444" & Chr(34) & "><font width=" & Chr(34) & "80%" & Chr(34) & "face=" & Chr(34) & "Arial" & Chr(34) & "color=" & Chr(34) & "#FFFFFF" & Chr(34) & "><small>"
 Reg_Estilo4 = "</strong></small></td></tr>"
 
 
 Set ObjFSO = CreateObject("Scripting.FileSystemObject")
 
 Set ObjDrivesCol = ObjFSO.Drives
 
 
 If Det_Scr = "Sim" then
    Call Cabeca()
 End If
 
 
   %><
table border="<% = Tab_Bord %>" width="<% = Tab_Larg %>" align="center" cellpadding="<% = Tab_Cell_Padding %>" cellspacing="1">
 
   <tr><td bgcolor="<% = Tab_Cab_Cor %>" colspan="2"><font face="Arial" color="<% = Tab_CabT_Cor %>"><strong><small>
          Geral</strong><br>
          </strong></small></td></tr>
         
         
          <%
          Response.Write Reg_Estilo1 & "Número de Drives:" & Reg_Estilo2 & Reg_Estilo3 & ObjDrivesCol.count & Reg_Estilo4
          %>
         
         
         
</table><br><br>
         
         
        <%


  For Each Drive in ObjDrivesCol
       


   %><table border="<% = Tab_Bord %>" width="<% = Tab_Larg %>" align="center" cellpadding="<% = Tab_Cell_Padding %>" cellspacing="1"><%
  
          %>
<tr><td bgcolor="<% = Tab_Cab_Cor %>" colspan="2"><font face="Arial" color="<% = Tab_CabT_Cor %>"><strong><small><%
          Response.Write "Drive " & Drive.DriveLetter & "</strong><br>"
          %>
</strong></small></td></tr><%


          'Nome do Volume
          If Drive.IsReady = True then
             Response.Write Reg_Estilo1 & "Nome:" & Reg_Estilo2 & Reg_Estilo3 & Drive.VolumeName & Reg_Estilo4
          End If
         
  
   'Número de Série
   If Drive.IsReady = True then
      Response.Write Reg_Estilo1 & "Nº de Série:" & Reg_Estilo2 & Reg_Estilo3 & Drive.SerialNumber & Reg_Estilo4
   End If
  
          'Drive Pronto?
          If Drive.Isready then
             Pronto = "Sim"
          Else
             Pronto = "Não"
          End If
          Response.Write Reg_Estilo1 & "Pronto?" & Reg_Estilo2 & Reg_Estilo3 & Pronto & Reg_Estilo4
                   
         
          'Tipo do Drive
          Select Case Drive.DriveType
           case 0
             Tipo = "Desconhecido"
           case 1
             Tipo = "Removível"
           case 2
             Tipo = "Fixo"
           case 3
             Tipo = "Drive de Rede"
           case 4
             Tipo = "CD-ROM"
           case 5
             Tipo = "Drive Virtual (RAM)"
          End Select
        
          Response.Write Reg_Estilo1 & "Tipo do Drive:" & Reg_Estilo2 & Reg_Estilo3 & Tipo & Reg_Estilo4
         
         
         
          'Espaço Total e Espaço Disponível
         
          If Drive.Isready = True then
             Response.Write Reg_Estilo1 & "Tamanho:" & Reg_Estilo2 & Reg_Estilo3 & FormatNumber(Drive.TotalSize / 1024, 0) & " Kb" & Reg_Estilo4
             Response.Write Reg_Estilo1 & "Espaço Livre:" & Reg_Estilo2 & Reg_Estilo3 & FormatNumber(Drive.AvailableSpace / 1024, 0) & " Kb" & Reg_Estilo4
          End If


          'Sistema de Arquivo
   If Drive.IsReady = True then
      Response.Write Reg_Estilo1 & "Sistema de Arquivos:" & Reg_Estilo2 & Reg_Estilo3 & Drive.Filesystem & Reg_Estilo4
   End If
            
      %>
</table><br><br><% 
          Next


 


 Set ObjFSO = Nothing


 '*******
 '* Fim *
 '******* 


 %>
  
  



Esta matéria foi postada originalmente no ASP4Developers por Ricardo Costa (site), que na época era "Programador Delphi, Java, ASP e PHP de uma produtora de Web Sites (www.icorp.com.br) e estou cursando graduação em Ciências da Computação na UNICAP". Hoje, vai saber...

0 comentários: