Passe as variaveis por valor sem ByVal

Se você deseja passar as variáveis por valor, para uma Sub ou Function que não teve seus argumentos declarados com ByVal, use '('e ')' em torno da variável que vc está passando como parâmetro.

Veja o código do exemplo. A variával Var2 tem seu valor alterado, porque foi passada por referência (default no VB até a versão 6), enquanto que a variável Var1 não, embora a sub MudaValor não teve seus primeiro argumento declarado como ByVal.

Sub MudaValor(Var1 As String, Var2 As String)

Var1 = "Valor alterado"
Var2 = "Valor alterado"

End Sub

'====================

Private Sub Form_Click()

Dim Var1 As String
Dim Var2 As String

Var1 = "O valor não foi alterado"
Var2 = "O valor não foi alterado"

MudaValor (Var1), Var2

Print Var1
Print Var2

Print

Var1 = "O valor não foi alterado"
Var2 = "O valor não foi alterado"

MudaValor Var1, Var2

Print Var1
Print Var2

End Sub

'===========================

Execute o programa, e no form que abrir, dê um clique no mesmo. O resultado das chamadas à Sub MudaValor aparecerão impressas no próprio form

Esta matéria foi postada originalmente no ASP4Developers por Valmir Cinquini (site), que na época era "Analista/Programador C#, VB.Net, ASP, VB, Javascript e T-SQL

www.cinquini.com.br/vcinquini>". Hoje, vai saber...

Validar Cartao de Credito

' Valida numero de cartao de credito
' Retorna True se valido, False se invalido
'
' Exemplo:
'  If ValidaCartaoCredito(Value:="1234-123456-12345") Then

Function ValidaCartaoCredito(Value As Variant) As Boolean
    Dim strTemp As String
    Dim intCheckSum As Integer
    Dim blnDoubleFlag As Boolean
    Dim intDigit As Integer
    Dim i As Integer

    On Error GoTo ErrorHandler

    ValidaCartaoCredito = True
    Value = Trim$(Value)

    If Len(Value) = 0 Then
        ValidaCartaoCredito = False
 Exit function
    End If

    ' Se mesmo depois de retirar nao-numericos, nao sobrou nada, foi digitado lixo
    For i = 1 To Len(Value)
        If IsNumeric(Mid$(Value, i, 1)) Then strTemp = strTemp & Mid$(Value, i, _
            1)
    Next
    If Len(strTemp) = 0 Then
        ValidaCartaoCredito = False
    End If

    'Diferentes tamanhos para diferentes bandeiras de CC
    Select Case Mid$(strTemp, 1, 1)
        Case "3"    'Amex
            If Len(strTemp) <> 15 Then
                ValidaCartaoCredito = False
            Else
                Value = Mid$(strTemp, 1, 4) & "-" & Mid$(strTemp, 5, _
                    6) & "-" & Mid$(strTemp, 11, 5)
            End If
        Case "4"    'Visa
            If Len(strTemp) <> 16 Then
                ValidaCartaoCredito = False
            Else
                Value = Mid$(strTemp, 1, 4) & "-" & Mid$(strTemp, 5, _
                    4) & "-" & Mid$(strTemp, 9, 4) & "-" & Mid$(strTemp, 13, 4)
            End If
        Case "5"    'Mastercard
            If Len(strTemp) <> 16 Then
                ValidaCartaoCredito = False
            Else
                Value = Mid$(strTemp, 1, 4) & "-" & Mid$(strTemp, 5, _
                    4) & "-" & Mid$(strTemp, 9, 4) & "-" & Mid$(strTemp, 13, 4)
            End If
        Case Else      'Lixo - nao e numero de cartao de credito
            If Len(strTemp) > 20 Then
                ValidaCartaoCredito = False
            End If
    End Select

    'Check Sum (Mod 10)
    intCheckSum = 0                                    
    blnDoubleFlag = 0                                  

    For i = Len(strTemp) To 1 Step -1                  
        intDigit = Asc(Mid$(strTemp, i, 1))             ' Isola o caracter

        If intDigit > 47 Then                           ' Pula se nao e um inteiro

            If intDigit < 58 Then
                intDigit = intDigit - 48                ' Remove ASCII bias

                If blnDoubleFlag Then                  
                    intDigit = intDigit + intDigit      ' primeiro duplica-o

                    If intDigit > 9 Then
                        intDigit = intDigit - 9        
                    End If

                End If
                blnDoubleFlag = Not blnDoubleFlag      
                intCheckSum = intCheckSum + intDigit   

                If intCheckSum > 9 Then                
                    intCheckSum = intCheckSum - 10      ' (mesmo que MOD 10 mas mais rapido)
                End If
            End If
        End If
    Next

    If intCheckSum <> 0 Then                            '  Deve totalizar zero
        ValidaCartaoCredito = False
    End If

ErrorHandler:
    Err.Raise Err.Number, "ValidaCartaoCredito", Err.Description

End Function

Esta matéria foi postada originalmente no ASP4Developers por Valmir Cinquini (site), que na época era "Analista/Programador C#, VB.Net, ASP, VB, Javascript e T-SQL

www.cinquini.com.br/vcinquini>". Hoje, vai saber...

Arquivo -> BLOB: Copie o conteudo de um arquivo para um campo BLOB

' Este codigo copia o conteudo de um arquivo para um campo BLOB.

Sub FileToBlob(fld As ADODB.Field, filename As String, _
    Optional ChunkSize As Long = 8192)
    Dim fnum As Integer, bytesLeft As Long
    Dim bytes As Long
    Dim tmp() As Byte
   
    ' Gera erro se o campo nao suporta o GetChunk.
    If (fld.Attributes And adFldLong) = 0 Then
        Err.Raise 1001, , "Field doesn't support the GetChunk method."
    End If

    ' Abre o arquivo; Gera erro se ele nao existir.
    If Dir$(filename) = "" Then Err.Raise 53, , "Ops! Arquivo nao encotrado."
   
    fnum = FreeFile
    Open filename For Binary As fnum

    ' Le o arquivo em pedacos e inclui dados ao campo BLOB.
    bytesLeft = LOF(fnum)
    Do While bytesLeft
        bytes = bytesLeft
        If bytes > ChunkSize Then bytes = ChunkSize
        ReDim tmp(1 To bytes) As Byte
        Get #1, , tmp
        fld.AppendChunk tmp
        bytesLeft = bytesLeft - bytes
    Loop
   
    Close #fnum
End Sub

Esta matéria foi postada originalmente no ASP4Developers por Valmir Cinquini (site), que na época era "Analista/Programador C#, VB.Net, ASP, VB, Javascript e T-SQL

www.cinquini.com.br/vcinquini>". Hoje, vai saber...

BLOB -> Arquivo: Copie o conteudo de um campo BLOB para um arquivo

' Este codigo copia o conteudo de um campo BLOB para um arquivo.

Sub BlobToFile(fld As ADODB.Field, filename As String, _
    Optional ChunkSize As Long = 8192)
    Dim fnum As Integer, bytesLeft As Long
    Dim bytes As Long
    Dim tmp() As Byte
    
    ' Gera erro se o campo nao suporta o GetChunk.
    If (fld.Attributes And adFldLong) = 0 Then
        Err.Raise 1001, , "Campo nao suporta o metodo GetChunk."
    End If

    ' Apaga o arquivo se ele ja existe
    ' e cria um novo.
    If Dir$(filename) <> "" Then Kill filename
    
    fnum = FreeFile
    Open filename For Binary As fnum
    ' Le o conteudo e escreve os dados no arquivo.
    bytesLeft = fld.ActualSize
    
    Do While bytesLeft
        bytes = bytesLeft
        If bytes > ChunkSize Then bytes = ChunkSize
        tmp = fld.GetChunk(bytes)
        Put #fnum, , tmp
        bytesLeft = bytesLeft - bytes
    Loop
    
    Close #fnum
End Sub

Esta matéria foi postada originalmente no ASP4Developers por Valmir Cinquini (site), que na época era "Analista/Programador C#, VB.Net, ASP, VB, Javascript e T-SQL

www.cinquini.com.br/vcinquini>". Hoje, vai saber...

Use a função Sleep da API para adicionar pausas ao seu programa

Não use um For...Next vazio para adicionar pausas
ao seus programas. Use a função Sleep da API, que
libera a CPU e deixa as outras aplicações
efetivamente trabalharem no sistema:

Declare Sub Sleep Lib "kernel32" (ByVal milliseconds As Long)

' pause for 5 seconds
Sleep 5000

Esta tecnica só funciona em edições 32 bits do Visual Basic; Não há função equivalente na API Win16 bits.

Esta matéria foi postada originalmente no ASP4Developers por Valmir Cinquini (site), que na época era "Analista/Programador C#, VB.Net, ASP, VB, Javascript e T-SQL

www.cinquini.com.br/vcinquini>". Hoje, vai saber...

Conte substrings com a função Replace

Voce pode usar a função Replace para simplificar (e até
otimizar) seu código. Por exemplo, a fim de contar o
número de ocorrências de uma substring dentro de uma
string, geralmente se precisa de um loop baseado na
função InStr:

Dim i As Long, count As Long
i = InStr(source, search)
Do While i
    count = count + 1
    i = InStr(i + 1, source, search)
Loop

Aqui vai um código em uma linha que faz
exatamente o mesmo. O truque esta em trocar
cada substring com outra string que é um
caracter maior, e então determinar a diferença
entre a string obtida e a original. Este
número é igual ao número de substituições
feitas, e portanto igual ao número de
substituições encontradas. (Note que o
código é mais conciso que o anterior, porém
um pouco mais lento que a solução anterior).

count = Len(Replace(Source, Search, Search & "*")) - Len(Source)

Esta matéria foi postada originalmente no ASP4Developers por Valmir Cinquini (site), que na época era "Analista/Programador C#, VB.Net, ASP, VB, Javascript e T-SQL

www.cinquini.com.br/vcinquini>". Hoje, vai saber...

Global.asa, Contador de page views e de usuários on-line

Em várias listas que sou assinante, vejo colegas em busca de uma solução para conhecer o total de usuários que estão acessando o site no momento. Este tipo de solução é bastante simples de ser implementada através do arquivo globa.asa.

O arquivo global.asa deve ser salvo no diretório raiz do site. É de boa prática, ter apenas um arquivo global.asa por aplicativo.

O objetivo será de criar um simples contador de page views e também um contador para usuários on-line. Abaixo, o script de nosso global.asa.

Arquivo Global.asa
*******************************************************
<SCRIPT LANGUAGE=VBSCRIPT RUNAT=SERVER>

Sub Application_OnStart
      Application("intTotUser") = 0
      Application("datServerUp") = Now()
      Application("intTotOnLine") = 0
End Sub

Sub Application_OnEnd
End Sub

Sub Session_OnStart
      Session.TimeOut = 10
      Application.Lock
            Application("intTotUser") = Application("intTotUser") + 1
            Application("intTotOnLine") = Application("intTotOnLine") + 1
      Application.Unlock
End Sub

Sub Session_OnEnd
      Application.Lock
            Application("intTotOnLine") = Application("intTotOnLine") - 1
      Application.Unlock
End Sub

</SCRIPT>
*******************************************************

:::::::::::::EXCLARECENDO AS DÚVIDAS:::::::::::::

-------------------------------------------------------
Sub Application_OnStart
      Application("intTotUser") = 0
      Application("datServerUp") = Date()
      Application("intTotOnLine") = 0
End Sub
-------------------------------------------------------

O procedimento Sub Application_OnStart somente é executado uma única vez após a primeira requisição atendida pelo aplicativo.

O ASP executa automaticamente o procedimento Sub Application_OnStart toda a vez que o aplicativo é iniciado. Exemplo: O servidor web é reiniciado, e em seguida um navegador requisita uma página do aplicativo.

Neste caso, o procedimento Sub Application_OnStart é executado e três novas variáveis Application serão criadas:

-------------------------------------------------------
Application("intTotUser") -> Nesta variável será armazenado o total de usuário que acessaram o site desde a ultima vez que o servidor web foi reinicializado.

Application("datServerUp") -> Nesta variável será armazenada a data da primeira requisição atendida pelo aplicativo.

Application("intTotOnLine") -> Nesta variável será armazenado o total de usuários que estão acessando a aplicação no momento.

-------------------------------------------------------
Sub Session_OnStart
      Session.TimeOut = 10
      Application.Lock
            Application("intTotUser") = Application("intTotUser") + 1
            Application("intTotOnLine") = Application("intTotOnLine") + 1
      Application.Unlock
End Sub
-------------------------------------------------------

O procedimento Sub Session_OnStart será executado toda a vez que uma nova sessão é criada.

Neste caso, foi usado esse procedimento para incrementar a variável Application "intTotUser" e "intTotOnLine". Toda a vez que uma nova sessão for criada, as variáveis Application serão incrementadas de um.

Observe que foi usado o método "Lock" e "Unlock" do objeto Application. Esses métodos já foram explicados em um artigo já publicado, mas para relembrar: O método "Lock" é usado para garantir que dois usuários não atualizem a mesma variável ao mesmo tempo. E "Unlock", é usado para liberar a variável e permitir uma nova atualização.

-------------------------------------------------------
Sub Session_OnEnd
      Application.Lock
            Application("intTotOnLine") = Application("intTotOnLine") - 1
      Application.Unlock
End Sub
-------------------------------------------------------

O procedimento Sub Session_OnEnd é executado toda a vez que uma sessão é finalizada pelo servidor. Um dos eventos poderia ser: 1) Foi usado o método Abandon do objeto Session 2) Tempo de inatividade da sessão foi atingida 3) O navegador foi finalizado.

Neste caso, foi usado este procedimento para subtrair 1 (um) da variável Application "intTotOnLine". Desta forma será possível saber a quantidade exata de usuários conectados à aplicação.

O procedimento Sub Application_OnEnd é executado toda a vez que a aplicação é finalizada. Não é comum você ver procedimentos neste evento, isso porque executar um evento depois que o aplicativo e finalizado está fora do escopo de produção. Um bom uso talvez deste evento seria para registrar em log a data e hora que o aplicativo foi finalizado.

SCRIPT PARA MOSTRAR O RESULTADO
-------------------------------

script_001.asp
*******************************************************
<%Response.Buffer=True%>

<html>
<head>
<title>Acessos On-Line</title>
</head>
<body>

<%
Dim intSessionId
intSessionId = Session.SessionID

Dim intTotOnLine
intTotOnLine = Application("intTotOnLine")

Dim intTotUser
intTotUser= Application("intTotUser")
%>

<p><b>Sessão Identificada:</b> <%=intSessionId%></p>
<p><b>Informações úteis:</b></p>
<p><b>Usuários On-Line:</b> <%=intTotOnLine%></p>
<p><b>Total de acessos até o momento:</b> <%=intTotUser%></p>
<p><b>Data da última inicialização:</b> <%=datServerUp%></p>

</body>
</html>
*******************************************************


Boa Programação!

Esta matéria foi postada originalmente no ASP4Developers por Leonardo da Silva Calado (site), que na época era "Usuário avançado de Dreamweaver ultradev e programador ASP, JSP, PHP, VISUAL BASIC e Condfusion.
tenho preferência por ASP uma linguagem de facil aprendizado.". Hoje, vai saber...

Informações adicionais sobre Cookies

Os cookies são pequenos arquivos do tipo texto armazenados no computador do usuário. Estes pequenos arquivos armazenam informações diversas definidas pelo programador do site. O usuário poderá bloquear o aceite dos cookies através do próprio navegador ou por outros programas com o mesmo objetivo. O uso de cookies é bastante comum em sistemas para medir audiência de visitação, registrar as preferências do usuário ou até mesmo rastrear seus cliques no site.

******************************************************
Atributo Descrição

Domain: Se especificado, o cookie será enviado somente para os solicitações deste domínio.

Expires: A data em que o cookie expira. Essa data deve ser definida para que o cookie seja armazenado no computador do usuário após a conclusão da sessão. Se este atributo não for definido com uma data posterior a atual, o cookie expirará quando a sessão for finalizada.

HasKeys: Especifica se o cookie contém chave retornando True/ False.

Path: Se especificado, o cookie será enviado sempre que houver uma requisição neste caminho. Se este atributo não for definido, o caminho do script asp que o criou será utilizado.

Secure: Indica que o cookie deve ser enviado somente se o Secure Sockets Layer estiver ativo.
******************************************************

Criar um cookie
Se o cookie especificado não existir, ele será criado. Se existir, ele apanhará o novo valor e o valor antigo será descartado. O script abaixo cria um cookie chamado MyCookie:

<%
Response.Cookies("MyCookie") = "Novo Cookie"
%>

Usa-se o objeto "Request" para recuperar o valor do cookie :

<%
Dim MyVar
MyVar = Request.Cookies("MyCookie")

Response.Write "<p><b>"&MyVar&"</b></p>"
%>

Armazenar o valor de uma variável
Para gravar um cookies com o conteúdo de uma variável, é necessário que você utilize a função CStr() para converte-la no tipo string.

<%
MyVar = Request.Form("strName")
Response.Cookies("MyCookie") = CStr(MyVar)
%>

Várias informações em um único Cookie
A coleção Cookie poderá armazenar múltiplos valores em um único Cookie

<%
Response.Cookies("MyCookie")("MyCity") = "Belo Horizonte"
Response.Cookies("MyCookie")("MySite") = "Suportebrasil.NET"
%>

Para recuperar o valor de uma das chaves :

******************************************************
<%
Dim MyCity
MyCity = Request.Cookies("MyCookie")("MyCity")

Dim MySite
MySite = Request.Cookies("MyCookie")("MySite")

Response.Write "<p><b>Cidade : "&MyCity&"</b></p>"
Response.Write "<p><b>Site : "&MySite&"</b></p>"
%>
******************************************************

A regra para atribuir o valor de uma variável a uma das chaves de um cookie é a mesma empregada para criar um cookie sem chave. Usa-se a função "CStr()".

Muita atenção a essa regra:

Uma atribuição subseqüente a "MyCookie" criado no script acima, sem a especificação de uma chave, causaria a destruição das chaves "MyCity" e "MySite". Veja o script abaixo :

<%
Response.Cookies("MyCookie") = "Belo Horizonte"
%>

No script acima, as chaves "MyCity" e "MySite" são destruídas e seus valores descartados. O cookie "MyCookie", agora contém o valor "Belo Horizonte".

Como complemento, se você atribuir uma chave a um cookie que não tem chave, o valor não chave desse cookie será destruído. Por exemplo : Se depois do código anterior for feito:

<%
Response.Cookies("MyCookie")("MyJob") = "Programador"
%>

O valor "Belo Horizonte" é destruído e a sub chave MyJob estará armazenando o valor Programador.

Cookie com Chaves
Para determinar se um cookie tem chaves, utilize a seguinte sintaxe :

<%
Response.Write Request.Cookies("MyCookie").HasKeys
%>

Se "MyCookie" for um dicionário de cookie, o valor impresso será "TRUE" caso contrário "FALSE".

Interagir entre as chaves de um cookie
Podemos interagir entre as chaves de um Cookie através da instrução For Each.

******************************************************
<%
For Each Subkey in Request.Cookies("MyCookie")
        Response.Write SubKey &" - "& Request.Cookies("MyCookie")(Subkey)
Next
%>
******************************************************

Se você interagir em um cookie que não tem chave, o mesmo não será executado. É uma boa prática checar se o cookie tem chaves. O script acima ficaria mais correto se fosse escrito dessa forma :

******************************************************
<%
If Request.Cookies("MyCookie").HasKeys then
        For Each Subkey in Request.Cookies("MyCookie")
               Response.Write SubKey &" - "& Request.Cookies("MyCookie")(Subkey)
        Next
End If
%>
******************************************************

Atributos de um cookie

******************************************************
<%
Response.Cookies("UserLogin") = "joses"
Response.Cookies("UserLogin").Expires = #31/12/2000#
Response.Cookies("UserLogin").Domain = "/suportebrasil.net/"
Response.Cookies("UserLogin").Path = "/artigos"
Response.Cookies("UserLogin").Secure = FALSE
%>
******************************************************

Boa Programação!

Esta matéria foi postada originalmente no ASP4Developers por Leonardo da Silva Calado (site), que na época era "Usuário avançado de Dreamweaver ultradev e programador ASP, JSP, PHP, VISUAL BASIC e Condfusion.
tenho preferência por ASP uma linguagem de facil aprendizado.". Hoje, vai saber...

Armazenando Informações em Cookies

A personalização está fazendo com que todos os usuários sejam identificados, mesmo para saber de onde vieram que hora chegaram e o que fizeram. Isso é bom ou ruim para a performance do servidor e da aplicação asp?

A minha resposta é : Tudo vai depender da real necessidade de manter a informação. Você como programador deve saber que os cookies podem ser destruídos pelos usuários assim que eles quiserem, por isso se for para manter uma informação de grande importância, que essa informação seja mantida no banco de dados da aplicação e não em cookies, que são pequenos arquivos armazenados no computador do usuário.

Um bom exemplo para o uso de cookies é a identificação do acesso do usuário e de suas preferências dentro do site. Isso é apenas para os webmasters conhecerem seu público. Mas os cookies também podem ser usados para manter informações ativas durante a permanência do usuário na aplicação. Ex: Controle de Acesso.

Vou mostrar um exemplo bem completo que tem como objetivo mostrar a funcionalidade básica do cookie. Como já foi dito, cookies são informações que podemos gravar no computador do usuário.

A coleção Cookies é usada para enviar um cookie para o navegador do usuário. Permite atribuir um novo valor a um cookie (se ele já existir); caso contrário, o cookie será criado e o valor será atribuído. Por alterarem valores do cabeçalho HTTP response, os valores da coleção Cookies devem ser enviados antes que qualquer código HTML seja enviado para o navegador, exceto se Response.Buffer estiver como True.

1) A página HTML cadastro1.htm cria um formulário simples para receber dois valores do usuário, que neste caso serão o nome e e-mail. Estes valores serão submetidos para página asp cadastro2.asp.

**************************************************
<html>
<head>
<title> Trabalhando com cookies</title>
</head>
<body>
<form method="post" name="cookiesform" action="cadastro2.asp">
<input type="text" name="nome" size="50"><br>
<input type="text" name="email" size="50"><br>
<input type="submit" value="Enviar dados"><br><br>
</form>
</body>
</html>
**************************************************

2) A página asp cadastro2.asp receberá os valores enviados pelo formulário da página cadastro1.htm e criará os cookies: nome e e-mail. Nesta mesma página, criaremos um formulário para solicitar os campos Cidade e Uf.

**************************************************
<%Response.Buffer=True%>
<html>
<head>
<title> Trabalhando com cookies</title>
</head>
<body>
<%
Dim nome,email
nome = Request.Form("nome")
email = Request.Form("email")
Response.Cookies("nome") = CStr(nome)
Response.Cookies("email") = CStr(email)
%>
<form method="post" name="cookiesform" action="cadastro3.asp">
<input type="text" name="cidade" size="50"><br>
<input type="text" name="uf" size="2"><br>
<input type="submit" value="Enviar dados"><br><br>
</form>
</body>
</html>
**************************************************

Os cookies armazenam dados do tipo string. É bom usar a função Cstr() para converter a variável para esse tipo.

3) A página asp cadastro3.asp vai ler o conteúdo dos cookies nome e email que foram criados pela página cadastro2.asp e apresentá-los como conteúdo de seu campo de formulário correspondente.

**************************************************
<%Response.Buffer=True%>
<html>
<head>
<title> Trabalhando com cookies</title>
</head>
<body>
<%
Dim nome,email,cidade,uf
nome = Request.Cookies("nome")
email = Request.Cookies("email")
cidade = Request.Form("cidade")
uf = Request.Form("uf")
%>
<form method="post" name="cookiesform" action="inserirdados.asp">
<input type="text" name="nome" size="50" value="<%=nome%>"><br>
<input type="text" name="email" size="50" value="<%=email%>"><br>
<input type="text" name="cidade" size="50" value="<%=cidade%>"><br>
<input type="text" name="uf" size="2" value="<%=uf%>"><br>
<input type="submit" value="Enviar dados"><br><br>
</form>
</body>
</html>
**************************************************

Se você executar os scripts acima, vai ver que o campo "nome" e "email" foram preenchidos pelos valores recuperados de seus respectivos cookies. Na prática é deste jeito que manipulamos cookies via script asp.

Boa Programação!

Esta matéria foi postada originalmente no ASP4Developers por Leonardo da Silva Calado (site), que na época era "Usuário avançado de Dreamweaver ultradev e programador ASP, JSP, PHP, VISUAL BASIC e Condfusion.
tenho preferência por ASP uma linguagem de facil aprendizado.". Hoje, vai saber...

Matando uma variavel do tipo Session() (ASP)

Para remover uma classe da memoria em um script, basta voce setar o objeto como nothing:

set myObjecto.myClass = nothing

Para fazer o mesmo com variaveis de sessao (session("<nome>"),  basta voce seta-la como Null:

session("blablabla") = null

e ela estara removida da memoria. Tome cuidado ao matar uma variavel. Voce pode precisar dela mais adiante!  8>)

Esta matéria foi postada originalmente no ASP4Developers por Valmir Cinquini (site), que na época era "Analista/Programador C#, VB.Net, ASP, VB, Javascript e T-SQL

www.cinquini.com.br/vcinquini>". Hoje, vai saber...